CATIA VBAでPowerCopyのインスタンスを作成する方法｜CATIAマクロの作成方法

CATIAにはパワーコピー(PowerCopy)という非常に便利な機能が存在しています。

そんなパワーコピーですが、実はCATIA VBAを使って[ドキュメントからインスタンスを作成]コマンドと同じ処理を行うことができます。つまりはCATIA VBAのループ文を使うことで大量のパワーコピーのインスタンスを一括で作成することが可能になるということです。

ある程度パワーコピーの知識は必要ですが基本的にはパワーコピーのインスタンス作成のコードは定型文なので、コピペしていくつかの要素を書き換えればすぐに使用可能になります。初見ではコード内容が複雑に見えますが、フェーズごとに見ていけば案外単純な構造をしているのでぜひ理解してみて下さい。

※本ページはパワーコピーについて理解している前提の内容になっています。
　パワーコピーについて知らない方は先にパワーコピーについて理解してから始めましょう。
　またVBAでパワーコピーを使用するには「KT1」ライセンスが必要です。

1. インスタンス元ドキュメントについて(パワーコピー)
2. VBAコード
3. コード解説
4. まとめ

インスタンス元ドキュメントについて(パワーコピー)

まずは本ページで使用するパワーコピーの元(リファレンス)となるドキュメントの構成を説明します。
パワーコピーの内容としては「丸座面を作成する」という機能になっています。

下画像の「Input」セット内にある2つのオブジェクトがパワーコピーの入力となります。
この2つのオブジェクトの入力を元に、「Output」セットが作成されます。
また、パラメータとしては「ﾊﾟﾗﾒｰﾀ.1」セット内の5つのパラメータが設定可能となっています。

手動でのインスタンス作成時は下画像のようになります。
座面中心点(◎)と基準ｻｰﾌｪｽ(水色)の入力をもとに丸座面(黄色)が作成されます。
このときパラメータを変更することで丸座面の形状を調節できるようになっています。

ここで重要なのは下記の部分です。この部分はコードに記載する内容です。
実際は下記の文字列ではなく自身のパワーコピーに記載している文字列を使うことになるので、上画像と比較してしっかりとどこの内容なのかを理解しておきましょう。

・ドキュメント名称　 “PowerCopy_OriginalDocument” (※実際はフルパス)
・パワーコピー名称　 “PowerCopy_丸座面”
・入力オブジェクト名称　“座面中心点” , “基準ｻｰﾌｪｽ”
・パラメータ名称　　　　“座面高さ” , “座面直径” , “座面角度” , “凸R” , “凹R”　　　

VBAコード

では上記ドキュメントのインスタンス作成のためのコードを解説していきます。
コード全体は下記の通りです。

※事前にパワーコピードキュメントとインスタンスを作成するドキュメントが必要です。
　下記コードはインスタンスを作成するドキュメント上で実行します。
　パワーコピードキュメントは手動時と同様に閉じておいて下さい。

Option Explicit
Sub CATMain()

 'ｱｸﾃｨﾌﾞﾄﾞｷｭﾒﾝﾄ等定義
    If TypeName(CATIA.ActiveDocument) <> "PartDocument" Then
       MsgBox "このマクロはPartDocument専用です。" & vbLf & _
              "CATPartに切り替えて実行してください。"
       Exit Sub
    End If
    
    Dim doc As PartDocument:        Set doc = CATIA.ActiveDocument
    Dim pt As Part:                 Set pt = doc.Part

 'InstanceFactory定義
    Dim insf As InstanceFactory:    Set insf = pt.GetCustomerFactory("InstanceFactory")
    
 'SelectElement2で入力ｵﾌﾞｼﾞｪｸﾄ1(座面中心点)をﾕｰｻﾞｰ選択で取得
    Dim sel:                    Set sel = doc.Selection
    Dim filter:                 filter = Array("Point")
    Dim status As String
    
    status = sel.SelectElement2(filter, "座面中心点を選択して下さい", False)
    If status <> "Normal" Then Exit Sub
    
    Dim input1 As Point
    Set input1 = sel.Item(1).Value
    sel.Clear
    
 'SelectElement2で入力ｵﾌﾞｼﾞｪｸﾄ2(基準ｻｰﾌｪｽ)をﾕｰｻﾞｰ選択で取得
    filter = Array("HybridShape")
    status = sel.SelectElement2(filter, "基準ｻｰﾌｪｽを選択して下さい", False)
    If status <> "Normal" Then Exit Sub
    
    Dim input2 As HybridShape
    Set input2 = sel.Item(1).Value
    sel.Clear    

       
 'ﾊﾟﾜｰｺﾋﾟｰﾄﾞｷｭﾒﾝﾄﾊﾟｽ
    Dim pc_path As String
    pc_path = "C:\Users\…\PowerCopy_OriginalDocument.CATPart"
    
 'ﾊﾟﾜｰｺﾋﾟｰ名称
    Dim pc_name As String
    pc_name = "PowerCopy_丸座面"


 '①ｲﾝｽﾀﾝｽ化ﾌﾟﾛｾｽを初期化
    insf.EndInstanceFactory
    insf.BeginInstanceFactory pc_name, pc_path
    
 '②ﾘﾌｧﾚﾝｽ初期化
    insf.BeginInstantiate
    
 '③ﾘﾌｧﾚﾝｽの入力ｵﾌﾞｼﾞｪｸﾄを指定
    insf.PutInputData "座面中心点", input1
    insf.PutInputData "基準ｻｰﾌｪｽ", input2
    
 '④ﾘﾌｧﾚﾝｽのﾊﾟﾗﾒｰﾀ値の設定(ｵﾌﾟｼｮﾝのため省略可)
    Dim parm As Parameter
    Set parm = insf.GetParameter("座面高さ")
    
    parm.ValuateFromString ("3mm")
 
 '⑤ﾘﾌｧﾚﾝｽのｲﾝｽﾀﾝﾝｽを作成
    Dim inst
    Set inst = insf.Instantiate
    
 '⑥ﾘﾌｧﾚﾝｽのｲﾝｽﾀﾝｽ作成を終了
    insf.EndInstantiate
    
 '⑦ｲﾝｽﾀﾝｽ化ﾌﾟﾛｾｽの終了
    insf.EndInstanceFactory
    
    pt.Update
    
End Sub

Option Explicit

Sub CATMain()

'ｱｸﾃｨﾌﾞﾄﾞｷｭﾒﾝﾄ等定義

If TypeName(CATIA.ActiveDocument) <> "PartDocument" Then

MsgBox "このマクロはPartDocument専用です。" & vbLf & _

"CATPartに切り替えて実行してください。"

Exit Sub

End If

Dim doc As PartDocument: Set doc = CATIA.ActiveDocument

Dim pt As Part: Set pt = doc.Part

'InstanceFactory定義

Dim insf As InstanceFactory: Set insf = pt.GetCustomerFactory("InstanceFactory")

'SelectElement2で入力ｵﾌﾞｼﾞｪｸﾄ1(座面中心点)をﾕｰｻﾞｰ選択で取得

Dim sel: Set sel = doc.Selection

Dim filter: filter = Array("Point")

Dim status As String

status = sel.SelectElement2(filter, "座面中心点を選択して下さい", False)

If status <> "Normal" Then Exit Sub

Dim input1 As Point

Set input1 = sel.Item(1).Value

sel.Clear

'SelectElement2で入力ｵﾌﾞｼﾞｪｸﾄ2(基準ｻｰﾌｪｽ)をﾕｰｻﾞｰ選択で取得

filter = Array("HybridShape")

status = sel.SelectElement2(filter, "基準ｻｰﾌｪｽを選択して下さい", False)

If status <> "Normal" Then Exit Sub

Dim input2 As HybridShape

Set input2 = sel.Item(1).Value

sel.Clear

'ﾊﾟﾜｰｺﾋﾟｰﾄﾞｷｭﾒﾝﾄﾊﾟｽ

Dim pc_path As String

pc_path = "C:\Users\…\PowerCopy_OriginalDocument.CATPart"

'ﾊﾟﾜｰｺﾋﾟｰ名称

Dim pc_name As String

pc_name = "PowerCopy_丸座面"

'①ｲﾝｽﾀﾝｽ化ﾌﾟﾛｾｽを初期化

insf.EndInstanceFactory

insf.BeginInstanceFactory pc_name, pc_path

'②ﾘﾌｧﾚﾝｽ初期化

insf.BeginInstantiate

'③ﾘﾌｧﾚﾝｽの入力ｵﾌﾞｼﾞｪｸﾄを指定

insf.PutInputData "座面中心点", input1

insf.PutInputData "基準ｻｰﾌｪｽ", input2

'④ﾘﾌｧﾚﾝｽのﾊﾟﾗﾒｰﾀ値の設定(ｵﾌﾟｼｮﾝのため省略可)

Dim parm As Parameter

Set parm = insf.GetParameter("座面高さ")

parm.ValuateFromString ("3mm")

'⑤ﾘﾌｧﾚﾝｽのｲﾝｽﾀﾝﾝｽを作成

Dim inst

Set inst = insf.Instantiate

'⑥ﾘﾌｧﾚﾝｽのｲﾝｽﾀﾝｽ作成を終了

insf.EndInstantiate

'⑦ｲﾝｽﾀﾝｽ化ﾌﾟﾛｾｽの終了

insf.EndInstanceFactory

pt.Update

End Sub

コード解説

ｱｸﾃｨﾌﾞﾄﾞｷｭﾒﾝﾄ等の定義

 'ｱｸﾃｨﾌﾞﾄﾞｷｭﾒﾝﾄ等定義
    If TypeName(CATIA.ActiveDocument) <> "PartDocument" Then
       MsgBox "このマクロはPartDocument専用です。" & vbLf & _
              "CATPartに切り替えて実行してください。"
       Exit Sub
    End If
    
    Dim doc As PartDocument:        Set doc = CATIA.ActiveDocument
    Dim pt As Part:                 Set pt = doc.Part

'ｱｸﾃｨﾌﾞﾄﾞｷｭﾒﾝﾄ等定義

If TypeName(CATIA.ActiveDocument) <> "PartDocument" Then

MsgBox "このマクロはPartDocument専用です。" & vbLf & _

"CATPartに切り替えて実行してください。"

Exit Sub

End If

Dim doc As PartDocument: Set doc = CATIA.ActiveDocument

Dim pt As Part: Set pt = doc.Part

まずはじめにアクティブドキュメントを定義をします。
今回のマクロはCATPartのみ有効なものなので、アクティブドキュメントがCATPart以外の場合はTypeName関数を使った条件分岐でマクロを終了するようにしています。つまり、アクティブドキュメントがCATPartの場合のみ変数「doc」にアクティブドキュメントを代入し、マクロの処理を続けます。

アクティブドキュメントが定義できたら「Partオブジェクト」も合わせて定義します。

　　
InstanceFactory定義

 'InstanceFactory定義
    Dim insf As InstanceFactory:    Set insf = pt.GetCustomerFactory("InstanceFactory")

1 2	'InstanceFactory定義 Dim insf As InstanceFactory: Set insf = pt.GetCustomerFactory("InstanceFactory")

つぎにインスタンスを作成するためのオブジェクトである「InstanceFactory」を定義します。

GSDで形状を作成するための「HybridShapeFactory」オブジェクトや、パーツデザインで形状を作成するための「ShapeFactory」オブジェクトと同じFactory系オブジェクトです。

定義方法は特殊で「pt.HybridShapeFactory」や「pt.ShapeFactory」のようにPartオブジェクトのプロパティとしては定義できません。InstanceFactoryオブジェクトはPartオブジェクトの「GetCustomerFactoryメソッド」を使って下記のように書くことで定義ができます。

InstanceFactory定義

Dim insf As InstanceFactory
Set insf = Partオブジェクト.GetCustomerFactory(“InstanceFactory”)

あとはInstanceFactoryオブジェクト内のメソッドを順に実行していくことでパワーコピーのインスタンスを作成することができます。

　
SelectElement2で入力ｵﾌﾞｼﾞｪｸﾄをﾕｰｻﾞｰ選択で取得

'SelectElement2で入力ｵﾌﾞｼﾞｪｸﾄ1(座面中心点)をﾕｰｻﾞｰ選択で取得
    Dim sel:                    Set sel = doc.Selection
    Dim filter:                 filter = Array("Point")
    Dim status As String
    
    status = sel.SelectElement2(filter, "座面中心点を選択して下さい", False)
    If status <> "Normal" Then Exit Sub
    
    Dim input1 As Point
    Set input1 = sel.Item(1).Value
    sel.Clear
    
 'SelectElement2で入力ｵﾌﾞｼﾞｪｸﾄ2(基準ｻｰﾌｪｽ)をﾕｰｻﾞｰ選択で取得
    filter = Array("HybridShape")
    status = sel.SelectElement2(filter, "基準ｻｰﾌｪｽを選択して下さい", False)
    If status <> "Normal" Then Exit Sub
    
    Dim input2 As HybridShape
    Set input2 = sel.Item(1).Value
    sel.Clear

'SelectElement2で入力ｵﾌﾞｼﾞｪｸﾄ1(座面中心点)をﾕｰｻﾞｰ選択で取得

Dim sel: Set sel = doc.Selection

Dim filter: filter = Array("Point")

Dim status As String

status = sel.SelectElement2(filter, "座面中心点を選択して下さい", False)

If status <> "Normal" Then Exit Sub

Dim input1 As Point

Set input1 = sel.Item(1).Value

sel.Clear

'SelectElement2で入力ｵﾌﾞｼﾞｪｸﾄ2(基準ｻｰﾌｪｽ)をﾕｰｻﾞｰ選択で取得

filter = Array("HybridShape")

status = sel.SelectElement2(filter, "基準ｻｰﾌｪｽを選択して下さい", False)

If status <> "Normal" Then Exit Sub

Dim input2 As HybridShape

Set input2 = sel.Item(1).Value

sel.Clear

InstanceFactoryオブジェクト内のメソッドを順に実行する前に、パワーコピーの入力オブジェクトとなるオブジェクトを取得しておきます。

ここではSelectionオブジェクトのSelectElement2メソッドを使ってユーザー選択により入力オブジェクトを取得していますが、入力したいオブジェクトさえ取得できれば別の方法でも問題ありません。

要は上記コードでいう「input1」「input2」の中にそれぞれ「座面中心点」「基準ｻｰﾌｪｽ」となるオブジェクトが入っていれば問題ないということです。オブジェクトの取得方法は作成するマクロに合わせて任意に書き換えて下さい。

　
ﾊﾟﾜｰｺﾋﾟｰﾄﾞｷｭﾒﾝﾄﾊﾟｽ / ﾊﾟﾜｰｺﾋﾟｰ名称の定義

 'ﾊﾟﾜｰｺﾋﾟｰﾄﾞｷｭﾒﾝﾄﾊﾟｽ
    Dim pc_path As String
    pc_path = "C:\Users\…\PowerCopy_OriginalDocument.CATPart"　'<- インスタンス元となるドキュメントのフルパスを入力
    
 'ﾊﾟﾜｰｺﾋﾟｰ名称
    Dim pc_name As String
    pc_name = "PowerCopy_丸座面"　'<- 作成したパワーコピーの名称を入力

'ﾊﾟﾜｰｺﾋﾟｰﾄﾞｷｭﾒﾝﾄﾊﾟｽ

Dim pc_path As String

pc_path = "C:\Users\…\PowerCopy_OriginalDocument.CATPart"　'<- インスタンス元となるドキュメントのフルパスを入力

'ﾊﾟﾜｰｺﾋﾟｰ名称

Dim pc_name As String

pc_name = "PowerCopy_丸座面"　'<- 作成したパワーコピーの名称を入力

つぎにパワーコピーを作成したインスタンス元となるドキュメントをコード上で定義していきます。
ここでは「pc_path=ドキュメントのパス」と「pc_name=パワーコピーの名称」を定義します。
使用するドキュメントを参照しながら上記コードを自身の内容に書き換えて下さい。

　
ﾘﾌｧﾚﾝｽの定義とｲﾝｽﾀﾝｽの作成

 '①ｲﾝｽﾀﾝｽ化ﾌﾟﾛｾｽを初期化
    insf.EndInstanceFactory
    insf.BeginInstanceFactory pc_name, pc_path
    
 '②ﾘﾌｧﾚﾝｽ初期化
    insf.BeginInstantiate
    
 '③ﾘﾌｧﾚﾝｽの入力ｵﾌﾞｼﾞｪｸﾄを指定
    insf.PutInputData "座面中心点", input1
    insf.PutInputData "基準ｻｰﾌｪｽ", input2
    
 '④ﾘﾌｧﾚﾝｽのﾊﾟﾗﾒｰﾀ値の設定(ｵﾌﾟｼｮﾝのため省略可)
    Dim parm As Parameter
    Set parm = insf.GetParameter("座面高さ")
    
    parm.ValuateFromString ("3mm")
 
 '⑤ﾘﾌｧﾚﾝｽのｲﾝｽﾀﾝﾝｽを作成
    Dim inst
    Set inst = insf.Instantiate
    
 '⑥ﾘﾌｧﾚﾝｽのｲﾝｽﾀﾝｽ作成を終了
    insf.EndInstantiate
    
 '⑦ｲﾝｽﾀﾝｽ化ﾌﾟﾛｾｽの終了
    insf.EndInstanceFactory
    
    pt.Update

'①ｲﾝｽﾀﾝｽ化ﾌﾟﾛｾｽを初期化

insf.EndInstanceFactory

insf.BeginInstanceFactory pc_name, pc_path

'②ﾘﾌｧﾚﾝｽ初期化

insf.BeginInstantiate

'③ﾘﾌｧﾚﾝｽの入力ｵﾌﾞｼﾞｪｸﾄを指定

insf.PutInputData "座面中心点", input1

insf.PutInputData "基準ｻｰﾌｪｽ", input2

'④ﾘﾌｧﾚﾝｽのﾊﾟﾗﾒｰﾀ値の設定(ｵﾌﾟｼｮﾝのため省略可)

Dim parm As Parameter

Set parm = insf.GetParameter("座面高さ")

parm.ValuateFromString ("3mm")

'⑤ﾘﾌｧﾚﾝｽのｲﾝｽﾀﾝﾝｽを作成

Dim inst

Set inst = insf.Instantiate

'⑥ﾘﾌｧﾚﾝｽのｲﾝｽﾀﾝｽ作成を終了

insf.EndInstantiate

'⑦ｲﾝｽﾀﾝｽ化ﾌﾟﾛｾｽの終了

insf.EndInstanceFactory

pt.Update

最後に本マクロの核部分となるインスタンスの作成を行っていきます。
またインスタンスの作成には先にリファレンス(インスタンス元)の定義が必要なので併せて行います。

順序をまとめるとInstanceFactoryオブジェクトのメソッドを下記の順で実行していくだけです。

① BeginInstanceFactory
② BeginInstantiate
③ PutInputData
④ GetParameter (パラメータがある場合のみ)　　　　　　　
⑤ Instantiate
⑥ EndInstantiate
⑦ EndInstanceFactory

　
続いて上記の各項目について詳しく解説していきます。

① BeginInstanceFactory (ｲﾝｽﾀﾝｽ化ﾌﾟﾛｾｽを初期化)

まずは、これからインスタンスを作成するプロセスを開始する宣言をします。
この宣言はBeginInstanceFactoryメソッドを使って行います。
　
引数としては(ドキュメントのパス , パワーコピーの名称)となっています。
引数の内容が間違っているとエラーが発生するので注意しましょう。

また、バグか仕様かはわかりませんがBeginInstanceFactoryメソッドを使用する前にEndInstanceFactoryメソッドを実行しないとエラーが発生するようになっています。
つまりは定型文として下記コードを書いておけば大丈夫です。

① BeginInstanceFactory (ｲﾝｽﾀﾝｽ化ﾌﾟﾛｾｽを初期化)

insf.EndInstanceFactory 　　‘エラー対策のために必要
insf.BeginInstanceFactory “ドキュメントのパス”,“パワーコピーの名称”

② BeginInstantiate (ﾘﾌｧﾚﾝｽ初期化 )

次にBeginInstantiate メソッドを使って①で指定したドキュメントパスとパワーコピー名称からインスタンス元として使用するパワーコピーの情報をすべて初期化します。

以降の③④では入力オブジェクトの設定やパラメータ値の設定/変更を行いますが、2回目以降の処理でそれらの変更が反映された状態にならないようにするための処理です。

VBAではその処理のなかでどれだけ変数の値を変更しても、2回目の処理ではそれらの変更はすべてリセットされた状態で再び処理が1から始まりますがそれと同じイメージです。

引数もないので定型文としては下記の1行のみです。

② BeginInstantiate (ﾘﾌｧﾚﾝｽ初期化 )

insf.BeginInstantiate

③ PutInputData (ﾘﾌｧﾚﾝｽの入力ｵﾌﾞｼﾞｪｸﾄを指定 )

次にPutInputDataメソッドでパワーコピーの入力となるオブジェクトを指定します。
本ページのマクロでは「SelectElement2メソッド」を使ってユーザー選択の取得により定義した「input1」と「input2」です。

ここではその「input1」と「input2」を使って入力を指定します。
「insf.PutInputData “座面中心点”, input1」のようにパワーコピー内で指定していたオブジェクト名とあわせて入力します。この場合パワーコピーの入力オブジェクトである“座面中心点”にはinput1に入っているオブジェクトが使用されるということを表しています。

入力オブジェクトが複数ある場合は再度PutInputDataメソッドを使って1行ずつ指定していきます。

定型文としては下記のようなコードになります。
入力オブジェクトすべてに対して記載する必要があるので注意しましょう。

③ PutInputData (ﾘﾌｧﾚﾝｽの入力ｵﾌﾞｼﾞｪｸﾄを指定 )

insf.PutInputData “入力オブジェクト名称1”, input1
insf.PutInputData “入力オブジェクト名称2”, input2
‘ :　 ※パワーコピーで設定している入力オブジェクトの数だけ記載

④ GetParameter (ﾘﾌｧﾚﾝｽのﾊﾟﾗﾒｰﾀ値の設定)

次にGetParameterメソッドを使いパワーコピーのパラメータの値を指定します。
パワーコピー内にパラメータが無い場合はGetParameterメソッドの使用は不要です。
また、パラメータの値をデフォルトで使う場合も使用は不要です。
つまりはパラメータの値をデフォルト値から変更する場合にのみ本メソッドを使用します。

パラメータ値の変更は「パラメータの取得」→「パラメータ値の変更」という順番で行います。

まず「Set parm =insf.GetParameter(“座面高さ”)」のように名指しでパラメータを取得します。
次に取得したパラメータである「parm」の「ValuateFromStringメソッド」を使って値を変更します。このとき「parm.ValuateFromString (“3mm”)」のようにして値を変更しますが、引数は文字列であるため「”3mm”」や「”20deg”」のように単位を付けた文字列を入力する必要があるので注意しましょう。

変更したいパラメータが複数の場合はそれぞれを取得して「ValuateFromStringメソッド」で値を変更しましょう。ここで変更しなかったパラメータはデフォルト値が使われます。

定型文としては下記のようなコードになります。

④ GetParameter (ﾘﾌｧﾚﾝｽのﾊﾟﾗﾒｰﾀ値の設定)

Dim parm As Parameter
Set parm = insf.GetParameter(“パラメータ名称”)
parm.ValuateFromString (“変更後の値”)

⑤ Instantiate (ﾘﾌｧﾚﾝｽのｲﾝｽﾀﾝﾝｽを作成)

次にInstantiateメソッドでこれまでに設定してきたリファレンスのインスタンスを作成します。
特に引数もないので定型文としては下記を書いておけばOKです。

⑤ Instantiate (ﾘﾌｧﾚﾝｽのｲﾝｽﾀﾝﾝｽを作成)

Dim inst
Set inst = insf.Instantiate

⑥ EndInstantiate (ﾘﾌｧﾚﾝｽのｲﾝｽﾀﾝｽ作成を終了)

次にインスタンス作成の終了の宣言をします。
この宣言にはEndInstantiateメソッドを使います。

「If」と「End If」,「For」と「Next」と同じ関係性で、②BeginInstantiateの対となる存在だと思っておけば大丈夫です。
特に引数もないので定型文としては下記を書いておけばOKです。

⑥ EndInstantiate (ﾘﾌｧﾚﾝｽのｲﾝｽﾀﾝｽ作成を終了)

insf.EndInstantiate

⑦ EndInstanceFactory (ｲﾝｽﾀﾝｽ化ﾌﾟﾛｾｽの終了)

最後にインスタンス作成プロセスの終了の宣言をします。
この宣言にはEndInstanceFactoryメソッドを使います。

⑥と同じで、①BeginInstanceFactoryの対の存在だと思ってもらえれば大丈夫です。
特に引数もないので定型文としては下記を書いておけばOKです。

⑦ EndInstanceFactory (ｲﾝｽﾀﾝｽ化ﾌﾟﾛｾｽの終了)

insf.EndInstanceFactory

以上でインスタンスの作成は完了です。
内容を見てもらえば分かった通り、①③④の一部さえ書き換えればあとはすべて同じ内容なのでコピペだけで十分にやっていけることが理解できたと思います。

まとめ

今回はCATIA VBAでPowerCopyのインスタンスを作成する方法を解説しました。

まとめると下記の通り順にInstanceFactoryオブジェクトのメソッドを使うだけです。
このときの引数がパワーコピーの名称や入力オブジェクトになっています。

⓪ InstanceFactory定義
① BeginInstanceFactoryメソッド
② BeginInstantiateメソッド
③ PutInputDataメソッド
④ GetParameterメソッド (パラメータがある場合のみ)　　　　　　　
⑤ Instantiateメソッド
⑥ EndInstantiateメソッド
⑦ EndInstanceFactoryメソッド

　　
今回の内容はかなり手動に近い方法のためイメージは付きやすいと思いますが、効率アップの要素はあまり感じられません。

しかし、パワーコピーのインスタンスの作成方法さえわかれば、一括でインスタンスを作成したり、複数のパワーコピーのインスタンスを順に字自動作成したりすることも可能になります。

色々試して「パワーコピー×VBA」の知識も付けてみて下さい。

目次へ戻る