CATIA VBAでオブジェクトのドメイン数を取得する関数｜CATIAマクロの作成方法

CATIAナレッジの式やルールにはナレッジ関数というものを独自の関数を使用することができます。オブジェクトのドメイン数を取得したいときはこのナレッジ関数の「nbDomains」を使うことで簡単に取得することができます。

ただ、この関数はあくまでもナレッジで使うことのできる関数であり、VBAで使うことはできません。
そこで本ページではVBAで使用可能な「nbDomains」の代わりとなる関数を作成したので紹介していきます。サンプルコードをコピペして呼び出せばすぐにでも使用できるので是非使ってみてください。

1. ナレッジ関数「nbDomains」とは
2. 手法① 式を作成し「nbDomains関数」を使う
3. 手法② 分解後にデータム数を数える
4. まとめ

ナレッジ関数「nbDomains」とは

CATIAのナレッジウェアには「nbDomains」という関数が用意されています。
この関数は下記のように書くことで式やルール内で使用することができ、オブジェクトのドメイン数を任意のパラメータに渡すことができます。

nbDomains関数の使い方

パラメータ = nbDomains(オブジェクト)

たとえば下画像でいうと、式を使って「形状ｾｯﾄ.1\境界.1」のドメイン数を「整数」パラメータの値に入れるような仕組みになっています。

　
VBAでは利用できないナレッジ関数

CATIAのナレッジには「nbDomains」を初めいくつもの関数が用意されています。
しかし、これらナレッジ関数ですが、VBAでは使用することが出来ないものも存在します。
「nbDomains」もこのVBAで使用することのできない関数の1つです。

そこで、「nbDomains」に相当するVBAの関数を2種類作成したので以下で紹介します。
2種類とも求めるまでの考えは違いますが結果は同じです。(ドメイン数が返ってくるだけ)

以下で紹介する関数はメインのプロシージャで下記のように書くことで利用できます。
できる限りナレッジ関数の「nbDomains」と同じような感覚で使えるようにしています。

VBA版 nbDomains関数の使い方

Dim res As Integer
res = nbDomains(iObj)
‘※iObjにはドメイン数を数えたいオブジェクト(HybridShape)を入力
　 resにはInteger型でiObjのドメイン数が返ってくる

手法① 式を作成し「nbDomains関数」を使う

サンプルコード

Function nbDomains(iObj As HybridShape) As Integer

    Dim pt As Part                  'ﾊﾟｰﾄ
    Dim hsf As HybridShapeFactory   'ﾊﾟﾗﾒｰﾀ/式 削除用
    Dim prm As IntParam             '新規ﾊﾟﾗﾒｰﾀ
    Dim strObjName As String        '引数ｵﾌﾞｼﾞｪｸﾄ名
    Dim strFormula As String        '式
    Dim fx As formula               '新規式
    Dim RefParm As Reference        'ﾊﾟﾗﾒｰﾀのReference
    Dim RefFx As Reference          '式のReference
    
    'ﾊﾟｰﾄ/ﾌｧｸﾄﾘｰ取得
    Set pt = CATIA.ActiveDocument.Part
    Set hsf = pt.HybridShapeFactory
    
    'Integer型のﾊﾟﾗﾒｰﾀ作成
    Set prm = pt.Parameters.CreateInteger("tmp", 0)
    
    '式作成 (xxx=nbDomains(xxx))
    strObjName = pt.Parameters.GetNameToUseInRelation(iObj)
    strFormula = "nbDomains(`" & strObjName & "`)"
    Set fx = pt.Relations.CreateFormula("tmp", "", prm, strFormula)
    
    'nbDomainsの結果を取得して返す
    nbDomains = Int(prm.ValueAsString)
    
    '作成したﾊﾟﾗﾒｰﾀと式を削除
    Set RefParm = pt.CreateReferenceFromObject(prm)
    Set RefFx = pt.CreateReferenceFromObject(fx)
    Call hsf.DeleteObjectForDatum(RefParm)
    Call hsf.DeleteObjectForDatum(RefFx)

End Function

Function nbDomains(iObj As HybridShape) As Integer

Dim pt As Part 'ﾊﾟｰﾄ

Dim hsf As HybridShapeFactory 'ﾊﾟﾗﾒｰﾀ/式削除用

Dim prm As IntParam '新規ﾊﾟﾗﾒｰﾀ

Dim strObjName As String '引数ｵﾌﾞｼﾞｪｸﾄ名

Dim strFormula As String '式

Dim fx As formula '新規式

Dim RefParm As Reference 'ﾊﾟﾗﾒｰﾀのReference

Dim RefFx As Reference '式のReference

'ﾊﾟｰﾄ/ﾌｧｸﾄﾘｰ取得

Set pt = CATIA.ActiveDocument.Part

Set hsf = pt.HybridShapeFactory

'Integer型のﾊﾟﾗﾒｰﾀ作成

Set prm = pt.Parameters.CreateInteger("tmp", 0)

'式作成 (xxx=nbDomains(xxx))

strObjName = pt.Parameters.GetNameToUseInRelation(iObj)

strFormula = "nbDomains(`" & strObjName & "`)"

Set fx = pt.Relations.CreateFormula("tmp", "", prm, strFormula)

'nbDomainsの結果を取得して返す

nbDomains = Int(prm.ValueAsString)

'作成したﾊﾟﾗﾒｰﾀと式を削除

Set RefParm = pt.CreateReferenceFromObject(prm)

Set RefFx = pt.CreateReferenceFromObject(fx)

Call hsf.DeleteObjectForDatum(RefParm)

Call hsf.DeleteObjectForDatum(RefFx)

End Function

　
コード内容

1つ目の方法は式を作成し、CATIAが本来持っている「nbDomains関数」を使う手法です。
CATIA VBAではナレッジウェアの関数は使えませんが、式そのものを作成することはできます。

つまり、下画像のようなパラメータと式を実際にVBAで作成してパラメータの値を取得し、取得後は作成したパラメータと式を削除すればいいだけのお話です。

VBAでパラメータと式を作成をするにはそれぞれ下記のように書きます。

パラメータの作成構文

Dim prm As Parameter ‘「prm」という名前の変数を宣言
Set prm = [Part].Parameters.CreateInteger(iName, iValue)

iName → 作成するパラメータの名前を入力
iValue → 作成するパラメータの初期値を入力

式の作成構文

Dim fx As Formula ‘「fx」という名前の変数を宣言
Set fx = _
[Part].Relations.CreateFormula(iName, iComment, iOutputParameter, iFormulaBody)

iName → 作成する式の名前を入力
iComment → 作成する式のコメントを入力(プロパティ内のコメント)
iOutputParameter → 作成する式の結果をアウトプットするパラメータの入力
iFormulaBody → 作成する式(文字列)を入力

　
あとは式作成の引数である「iFormulaBody」部分に「”nbDomains(xxx)”」のような「nbDomains関数」を使った式(文字列)を入れるだけです。これにより「パラメータの値=ドメイン数」となるので「prm.ValueAsString」として値を抜き出せばそれがドメイン数となります。

「(xxx)」にあたる、オブジェクト名の取得方法はサンプルコードを参照下さい。
(GetNameToUseInRelationというメソッドを使えば簡単に取得できます)

パラメータ/式の削除は「HybridShapeFactoryオブジェクト」の「DeleteObjectForDatumメソッド」を使います。名前的にデータムオブジェクトしか削除できなさそうなメソッドですが、Part内のオブジェクトなら大体のものは削除できます。(処理の結果としてはSelectionオブジェクトのDeleteメソッドとほぼ同じ)

DeleteObjectForDatumメソッド使い方

Call [HybridShapeFactory].DeleteObjectForDatum(RefObj)
‘※RefObjには削除したいオブジェクトのReferenceを入力

手法② 分解後にデータム数を数える

サンプルコード

Function nbDomains(iObj As HybridShape) As Integer

    Dim pt As Part                  'ﾊﾟｰﾄ
    Dim hsf As HybridShapeFactory   'ﾃﾞｰﾀﾑ 作成/削除用
    Dim RefObj As Reference         '引数ｵﾌﾞｼﾞｪｸﾄのReference
    Dim Dtms() As Variant           '分解後のﾃﾞｰﾀﾑ格納用
    Dim refDtm As Reference         'ﾃﾞｰﾀﾑのReference
    Dim i As Integer                'ｶｳﾝﾄ変数
    
    'ﾊﾟｰﾄ取得
    Set pt = CATIA.ActiveDocument.Part
    
    'HybridShapeFactory取得
    Set hsf = pt.HybridShapeFactory
    
    '分解(ﾃﾞｰﾀﾑ作成)
    Set RefObj = pt.CreateReferenceFromObject(iObj)
    Dtms = hsf.AddNewDatums(RefObj)
    
    'ﾄﾞﾒｲﾝ数を返す
    nbDomains = UBound(Dtms) + 1
    
'    '※形状ｾｯﾄにﾃﾞｰﾀﾑを出力(画面に表示したい場合はコメントを解除)※逆に下項目のﾃﾞｰﾀﾑ削除はｺﾒﾝﾄｱｳﾄのこと
'    Dim hb As HybridBody
'    Set hb = pt.HybridBodies.Add
'    For i = LBound(Dtms) To UBound(Dtms)
'        Call hb.AppendHybridShape(Dtms(i))
'    Next i
    
    '作成したﾃﾞｰﾀﾑを削除
    For i = LBound(Dtms) To UBound(Dtms)
        Set refDtm = pt.CreateReferenceFromObject(Dtms(i))
        Call hsf.DeleteObjectForDatum(refDtm)
    Next i

End Function