直線のベクトルを取得してリストに表示するマクロ｜CATIAマクロの作成方法

• 1. 作成するマクロの内容
• 2. マクロ実行のための事前準備
• 3. 完成コード
• 4. コードの解説
• 5. まとめ

マクロ実行のための事前準備

今回のマクロではユーザーフォーム(UserForm)を使っているので、事前にユーザーフォームを作っておく必要があります。

マクロライブラリー上で左クリックし[Insert]＞[UserForm]をクリックします。
するとユーザーフォームが作成されるので、プロパティウィンドウから名前(Name)を「UserForm1」に変更します。(初めて作成する場合はデフォルトで「UserForm1」となっています)

次に今回のマクロで使用する「Label」「ListBox」「TextBox」「CommandButton」というコントロールも事前に作成しておきます。[ToolBox]ウィンドウの各アイコンをクリックし以下のように配置してください。(※大きさや配置はコード上で行うため、適当な位置に配置するだけでOKです)

コントロールが作成できたらユーザーフォームのときと同じように名前を変更します。
(新規作成の場合はどれもデフォルトネームとなっています)

以上で事前準備は完了です。上記で設定した名前のユーザーフォームとコントロールが"存在"さえしていればこのマクロの実行は可能になります。

完成コード

マクロの完成コードは以下のとおりです。
モジュールに入力するコードとユーザーフォームに入力するコードがあります。

モジュール(Module1)コード

'<モジュールコード>

Option Explicit
Public SELArray()　　
Public SEL              'UserForm1でも使うため「Public」で宣言

Sub CATMain()

On Error Resume Next             'キャンセル時にエラーが出るので無視させる

Set SEL = CATIA.ActiveDocument.Selection
SEL.Clear

Dim FilterArray(0)
FilterArray(0) = "HybridBody"    '形状セット(HybidBody)以外は選択できないようにする
 
Dim Msg As String
Msg = "形状セットを選択してください。"
 
Select Case SEL.SelectElement2(FilterArray, Msg, False)
    Case "cancel", "undo", "redo"
    Exit Sub                  'キャンセルしたらマクロを終了
End Select
 
Dim SELHB As AnyObject
Set SELHB = SEL.Item(1).Value     'SELHBにユーザーが選択した形状セットを入れる
 
SEL.Add SELHB
SEL.Search ("type=直線,sel")      'SELHB内の直線を検索&選択(英語環境の場合は[直線]を[Line]に変更)

'SELHB内の直線の数をカウント
Dim SELCou As Integer
SELCou = SEL.Count

'形状セットの中身を確認
If SELCou = 0 Then
  MsgBox "選択した形状セットには[直線]が入っていません。"
  Exit Sub
End If

ReDim SELArray(SELCou)   'はじめに宣言した配列の中身をSELCou個にする
Dim GetArray(3)          '単位ベクトル(x,y,z)を格納する配列を用意
Dim i As Integer
For i = 1 To SELCou

    Dim SELLine '(As Line) ← Variant型で宣言
    Set SELLine = SEL.Item(i).Value

  '直線の単位ベクトル成分を取得
    GetArray(3) = SELLine.GetDirection(GetArray)

    Dim x1 As Double
    Dim y1 As Double
    Dim z1 As Double
    
  '小数点第2位までの値に変換して各成分に代入
    x1 = Round(GetArray(0), 2)
    y1 = Round(GetArray(1), 2)
    z1 = Round(GetArray(2), 2)

  'UserForm1にあるListBox1の中に取得した値を代入
    With UserForm1.ListBox1
      .ColumnCount = 4
      .ColumnWidths = "58;43;43;43"

      .AddItem ""
      .List(i - 1, 0) = SELLine.Name
      .List(i - 1, 1) = x1
      .List(i - 1, 2) = y1
      .List(i - 1, 3) = z1
    End With
    
    Set SELArray(i) = SELLine　 'SETHB内の直線を上から順に配列の中に入れていく(UserFormコード ※1のため)

Next i

UserForm1.Show vbModeless   'UserFrom1を起動
SEL.Clear

End Sub

ユーザーフォーム(UserForm1)コード

'<ユーザーフォームコード>

Option Explicit
Private Sub UserForm_Initialize()  'このUserFormが表示された時に以下を実行

'UserForm1のプロパティ調整
With Me
    .Caption = "単位ベクトル成分取得"
    .Width = 220
    .Height = 165
End With

'ListBox1のプロパティ調整
With Me.ListBox1
    .Left = 10
    .Top = 20
    .Width = 195
    .Height = 90
    .SetFocus
End With

'Label1のプロパティ調整
With Me.Label1
    .Left = 10
    .Top = 10
    .Width = 194
    .Caption = "       名称        |        X        |        Y        |         Z        "
    .BorderStyle = fmBorderStyleSingle
End With

'TextBox1のプロパティ調整
With Me.TextBox1
    .Left = 10
    .Top = 117
    .Width = 100
    .TextAlign = fmTextAlignCenter
    .Height = 18
End With

'CommandButton1のプロパティ調整
With Me.CommandButton1
    .Caption = "コピー"
    .Left = 143
    .Top = 117
    .Height = 18
    .Width = 60
End With

End Sub
'――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――
Private Sub CommandButton1_Click()  'CommandButton1をクリックしたとき以下を実行

'TextBox1の値を選択しコピー
With TextBox1
    .SelStart = 0
    .SelLength = Len(.Value)
    .Copy
End With

End Sub
'――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――
Private Sub ListBox1_Click()  'ListBox1をクリックしたとき以下を実行

SEL.Clear

'取得した成分を『(x,y,z)』のかたちでTextBox1に表示
TextBox1.Value = "( " & ListBox1.List(ListBox1.ListIndex, 1) & " , " & _
                      ListBox1.List(ListBox1.ListIndex, 2) & " , " & _
                      ListBox1.List(ListBox1.ListIndex, 3) & " )"
                      
'リストで選択したものを仕様ツリー上でも選択状態にする ※1
SEL.Add SELArray(ListBox1.ListIndex + 1)　

End Sub

※Project Explorerの左上にある[View Code]アイコンをクリックするとユーザーフォーム内にコードを書くことが出来ます。
上記のコードはココに書き込んでください。

まず大前提として今回のマクロの肝となるのが「直線のベクトルの取得方法」です。
ヘルプで「Vector」と検索したところ「Lineオブジェクト」のメソッドに「GetDirection」というものがありました。このメソッドの説明文は以下のとおりです。

Role: Returns the unit-vector pointing in the direction of the line.
(役割：直線の方向を指す単位ベクトルを返す)