csv_Functionsモジュールの実装｜Excel VBAでMNIST機械学習

本ページでは実際に自身の描いた手描き文字の識別を行うための準備を行います。
手書き文字をニューラルネットワークに読み込ませるには、MNISTデータと同じように入力データ(手書き文字データ)を28×28の計784個の数値に変換する必要があります。

というわけで、ここでは選択したbmpファイルを読み込み、数値として変換するための「csv_Functions」というモジュールを実装していきます。

注意

本ページからはニューラルネットワークによる推論フェーズの内容です。
ニューラルネットワークの実装ができていない方はメインページの「ニューラルネットワーク作成編」を参考にニューラルネットワークの実装を先に行ってください。

Contents

1. csv_Functionsモジュールの実装
2. Function bmp_to_csv
3. Function AlignBinaryData
4. まとめ

csv_Functionsモジュールの実装

まずは標準モジュールで「csv_Functions」というモジュールを作成します。

ニューラルネットワーク作成編で実装したっモジュールは「Option Base 1」を使っていましたが、ここでは使わないので注意して下さい。

以下はcsv_Functionsモジュールの全コードです。

'VBA csv_Functions(module)
Option Explicit
'――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――
Function bmp_to_csv() As Long()

    Application.ScreenUpdating = False
    
    Dim FilePath As Variant
    FilePath = Application.GetOpenFilename
    If FilePath = False Then
        End
    End If

    Dim FileSize As Long
    FileSize = FileLen(FilePath)
    If FileSize = 0 Then
        MsgBox "選択したファイルは有効ではありません。"
        Exit Function
    End If

    
    Dim FileID As Integer
    FileID = FreeFile

    Open FilePath For Binary As #FileID

    Dim BinaryData() As Byte
    ReDim BinaryData(0 To FileSize - 1)

    Get #FileID, , BinaryData
    Close #FileID
    
    If Not (BinaryData(0) = 66 And BinaryData(1) = 77) Then
        MsgBox "bmp画像を選択してください。"
        Exit Function
    End If


    'バイナリデータからピクセル値データのみを抜き取る
    
    Dim i As Long
    Dim Data() As Long
    Dim RGBData() As Long
    Dim GrayData() As Long
    
    ReDim Data(UBound(BinaryData) - 53)
    ReDim RGBData(UBound(BinaryData) - 53) 'NNで使うため配列の1番目から値を格納(0番目は空にする)

    For i = 1 To UBound(RGBData)
        RGBData(i) = BinaryData(i + 53)
    Next i
    
    
    'RGBデータをグレースケールデータに変換(学習データと入力値を揃える)
    
    ReDim GrayData(UBound(RGBData) / 3) '0番目は空にする
    
    For i = 1 To UBound(GrayData)
            GrayData(i) = Abs((RGBData((i - 1) * 3 + 1) * 0.11 + _
                               RGBData((i - 1) * 3 + 1 + 1) * 0.59 + _
                               RGBData((i - 1) * 3 + 1 + 2) * 0.3) - 255)
    Next i
    
    Data = AlignBinaryData(GrayData)

    Application.ScreenUpdating = True
    
    bmp_to_csv = Data

End Function
'――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――
Function AlignBinaryData(ByRef Data() As Long) As Long()

    Dim i As Long
    Dim j As Long
    Dim cnt As Long
    
    Dim out() As Long
    ReDim out(UBound(Data))
    
    cnt = 1
    For i = 28 To 1 Step -1
        For j = 27 To 0 Step -1
            out(cnt) = Data((i * 28) - j)
            cnt = cnt + 1
        Next j
    Next i
    
    AlignBinaryData = out

End Function

以下では各関数で何を行っているかを解説していきます。